Hi
I downloaded the SiC 1700V device SPICE model file from Microchip as attached (MCHP_MSCxxxSMA170_L1.lib)
https://www.microchip.com/en-us/product/msc035sma170#
This file contains subcks for different 1700V devices.
I copied the text relevant to the device that I am interested in (MSC750SMA170S_L1) & paste it in QSPICE. It went through usual process of creating symbol. ( I checked the check box ‘Include Entire File’)
When I try to use this in standard buck converter as a switch instead of NMOSFET from the Qspice library, it gives Fatal error as:
Fatal error: Timestep too small(3.25125e-18) at t=2.501e-05
I tried uploading the file here but it does not allow me. Could you please help me to fix this issue
Following is the subckt that I have copied and paste
*******************************************************************************
*******************************************************************************
* MSC750SMA170S_L1, 750mOhm, 1700V SiC MOSFET, TO-268
*******************************************************************************
********************* D G S *************************************************
.subckt MSC750SMA170S_L1 10 20 30 PARAMS: LAM1_=0 LAM2_=0 GM_=1.0 VTO_=2.0 TEMP_=27
*#ASSOC Category=NMOS Symbol=nmos_sic
Lg 20 21 4.5n
Rg 20 21 2
Ls 30 31 4n
Rs 30 31 2
XM1 10 21 31 MSCSICFET1700_L1 PARAMS: LAM1={LAM1_} LAM2={LAM2_} TEMP={TEMP_} GM={GM_} VTO={VTO_} MDE=0.050944669365722
.ends MSC750SMA170S_L1
*
* Version:
* 2022 Sept 15
*
* BD Continuity Mod
*
*******************************************************************************
***************************** D G S *****************************************
.SUBCKT MSCSICFET1700_L1 12 22 32 PARAMS: TEMP=27 LAM1=5 LAM2=2 GM=1 VTO=4.3 MDE=1
* Ref U07354_35_170
.param vt = {VTO - TEMP*0.5/150} ; Threshold defined by functions, not dat sheet
EfVDS 100 0 value= {V(42,32)}
EfVGS 101 0 value={V(23,32)-vt}
EfVGD 102 0 value={V(23,42)-vt}
G13 42 32 value={v(105)}
G14 42 32 value={v(108)}
R13 42 32 1G
R20 22 23 { 0.85/MDE } ; Lumpted gate resistance
XGD 42 23 Cgd1700_L1 PARAMS: SC= {MDE}
R21 23 42 1G
R23 23 32 1G
*Xgs 23 32 42 32 Cgs1700_L1 PARAMS: SC= {MDE}
Xgs 23 32 Cgs1700_L1B PARAMS: SC= {MDE}
R24 23 32 1G
R40 12 42 {k0/mde}
G41 42 32 value = {v(109)}
Xds 42 32 Cds1700_L1 PARAMS: SC= {MDE}
.param kd22 = {2.79-0.0016*TEMP} ; Barrier Potential
.param kd23 = {0.480/2.606} ; Identity factor
.param kd20 = {exp(-kd22/kd23)}
EIbd2 109 0 value = {mde*(kd20- exp((-v(100)-kd22)/kd23))}
.param ILIM = {440.0*(1 - 1.2e-3 * TEMP)*GM} ; Vg^2 limit without SCE
.param k4 = {0.034233-k0-1.1334e-5*TEMP+9.0903E-7*TEMP*TEMP} ; Channel resistance - shared
.param VGM = 20 ; Vg params are taken
.param VFAM = 1700 ; Voltage rating
.param k0 = 0.011 ; BD shared resistance
.param k1 = {1/(k4*(vgm-vt))}
Ek2 107 0 value = {((v(100)+LAM1)/(v(100)+LAM2))*ILIM/((vgm-vt)*(vgm-vt))}
Efb 106 0 value = {(k1*v(100)*v(107)*v(103)*v(103))/(k1*v(100)+v(107)*v(103))}
Eremapvgs 103 0 value= {v(101)*v(101)*(0.141-0.0285*v(101)+0.00011242*30*v(101)*v(101))
+/(1+v(101)*v(101)*(-0.0058048+0.00038844*v(101)+0.0001124*v(101)*v(101)))}
Eremapvgd 104 0 value= {v(102)*v(102)*(0.141-0.0285*v(102)+0.00011242*30*v(102)*v(102))
+/(1+v(102)*v(102)*(-0.0058048+0.00038844*v(102)+0.0001124*v(102)*v(102)))}
Efcond1 105 0 value= {mde*(if(v(100)>0,if(v(101)>0,v(106),0),0))}
Efcond2 108 0 value = {mde*(if(v(100)<0,if(v(102)>0,k1*v(104)*v(100),0),0))}
.ends
.subckt Cds1700_L1 1 2 PARAMS: SC = 1
Ecopy 3 6 1 2 1.0
Vsense 0 6 0
Cref 3 0 {1e-12*SC}
Hsense 10 0 Vsense 1.0
Gout 1 2 VALUE = {v(10)* ((4e3+140*V(1,2)**2)/(1+0.05*v(1,2)**2.4))}
.ends
.subckt Cgd1700_L1 1 2 PARAMS: SC = 1
Ecopy 3 6 1 2 1.0
Vsense 0 6 0
Cref 3 0 {1e-12*SC}
Hsense 10 0 Vsense 1.0
Gout 1 2 VALUE = {v(10)* ((2200+41*V(1,2)**2)/(1+0.2*v(1,2)**2.4))}
.ends
.subckt Cgs1700_L1 1 2 8 9 PARAMS: SC = 1
Ecopy 3 6 1 2 1.0
Vsense 0 6 0
Cref 3 0 {1e-12*SC}
Hsense 10 0 Vsense 1.0
Gout 1 2 VALUE = {V(10)* ((5300+2000*V(8,9)**2)/(1+0.6*v(8,9)**2))}
.ends
.subckt Cgs1700_L1B 1 2 PARAMS: SC = 1
Cref 1 2 {3.4e-9*SC}
.ends