* ------------------------------------------------------------------------------
* 
* DISCLAIMER
* 
* INFINEON'S MODEL TERMS OF USE
* 
* BY DOWNLOADING AND/OR USING THIS INFINEON MODEL ("MODEL"), THE USER
* (INCLUDING YOU) AGREES TO BE BOUND BY THE TERMS OF USE HERE STATED. IF USER
* DOES NOT AGREE TO ALL TERMS OF USE HERE STATED, USER SHALL NOT DOWNLOAD,
* USE OR COPY THE MODEL BUT IMMEDIATELY DELETE IT (TO THE EXTENT THAT IT
* WAS DOWNLOADED ALREADY).
* 
* 1. SCOPE OF USE
* 1.1 Any use of this Model provided by Infineon Technologies AG is subject
*     to these Terms of Use.
* 1.2 This Model, provided by Infineon, does not fully represent all of the
*     specifications and operating characteristics of the product to which
*     this Model relates.
* 1.3 This Model only describes the characteristics of a typical product.
*     In all cases, the current data sheet information for a given product
*     is the final design guideline and the only actual performance
*     specification. Although this Model can be a useful tool to evaluate
*     the product performance, it cannot simulate the exact product performance
*     under all conditions and it is also not intended to replace
*     bread-boarding for final verification.
* 
* 2. IMPORTANT NOTICE
* 2.1 Infineon Technologies AG ("Infineon") is not and cannot be aware of the
*     specific application of the Infineon's Model by User. However, Model may
*     from time to time be used by User in potentially harmful and/or life-
*     endangering applications such as traffic, logistic, medical, nuclear
*     or military applications or in other applications where failure of the
*     Model may predictably cause damage to persons' life or health or to
*     property (hereinafter "Critical Applications").
* 2.2 User acknowledges that Infineon has not specifically designed or
*     qualified the Model for Critical Applications that the Model may contain
*     errors and bugs and that User is required to qualify the Model for
*     Critical Applications pursuant to the applicable local quality, safety
*     and legal requirements before permitting or giving access to any such use.
* 
* 3. CONFIDENTIAL INFORMATION
*     User shall treat ideas, concepts and information incorporated in the
*     Model, the documentation and the content of this Terms of Use (together
*     hereinafter "Confidential Information") confidential, not disclose it to
*     any third party unless otherwise agreed in writing between User and
*     Infineon, not use it for any other purposes than using the Model for
*     simulation and testing purposes only.
* 
* 4. WARRANTY
* 4.1 User acknowledges that the Model is provided by Infineon under this Terms
*     of Use is provided free of charge and "AS IS" without any warranty or
*     liability of any kind and Infineon hereby expressly disclaims any
*     warranties or representations, whether express, implied, statutory or
*     otherwise, including but not limited to warranties of workmanship,
*     merchantability, fitness for a particular purpose, defects in the
*     Model, or non-infringement of third parties intellectual property rights.
* 4.2 Infineon reserves the right to make corrections, deletions, modifications,
*     enhancements, improvements and other changes to the Model at any time
*     or to move or discontinue any Model without notice.
* 
* 5. LIABILITY
* 5.1 Nothing in this Terms of Use shall limit or exclude Infineon's liability
*     under mandatory liability laws, for injuries to life, body or health,
*     for fraudulent concealment of defects in the software, or in cases
*     of Infineon's intentional misconduct or gross negligence.
* 5.2 Without prejudice to Sections 5.1, in cases of Infineon's slight
*     negligent breach of obligations that restrict essential rights or duties
*     arising from the nature of this Terms of Use in a way that there is a
*     risk of non-achievement of the purpose of this Terms of Use or of an
*     obligation whose observance User regularly may trust in and whereas
*     compliance with only makes proper execution of this Terms of Use
*     possible, Infineon's liability shall be limited to the typically,
*     foreseeable damage.
* 5.3 Without prejudice to Sections 8.1 and 8.2, Infineon's liability under
*     this Agreement shall be excluded in all other cases.
* 
* 6. EXPORT REGULATIONS
*     The User shall comply with all applicable national and international
*     laws and regulations, in particular the applicable export control
*     regulations and sanction programs. The User also agrees not to
*     export, re-export or transfer any software or technology developed
*     with or using information, software or technology offered by Infineon,
*     in violation of any applicable laws or regulations of the competent
*     authorities. Further, the User shall neither use any products,
*     information, software and technology offered by Infineon in or in
*     connection with nuclear technology or weapons of mass destruction
*     (nuclear, biological or chemical) and carriers thereof nor supply
*     military consignees.
* 
* 7. TERMINATION OF USE PERMIT
*     If the User violates these Terms of Use, such User's permit to use
*     this Model terminates automatically. In addition, Infineon may
*     terminate the User's permit to use this Model at its discretion and
*     at any time regardless of any violation of these Terms of Use. In
*     any of the foregoing events, the User is obliged to immediately destroy
*     any content that has been downloaded or printed from Infineon's website.
* 
* 8. MISCELLANEOUS
* 8.1 These Terms of Use are subject to the laws of the Federal Republic
*     of Germany with the exception of the United Nations on Purchase
*     Contracts on the International Sale of Goods dated April 11, 1980 (CISG).
*     The exclusive place of jurisdiction is Munich, Germany.
* 8.2 Should any provision in these Terms of Use be or become invalid, the
*     validity of all other provisions or agreements shall remain unaffected
*     thereby.
* 
* ------------------------------------------------------------------------------
* 
* Title:    INFINEON Power Transistors Simulation Models for PSpice
* Description: n-channel Transistors
*                 OptiMOS5 120V
* Authors:  Dr. Elmar Gondro, Tel: +49/89/234-29391
*           Sebastian Koch,   Tel: +49/89/234-89858
* Email:    Elmar.Gondro@Infineon.com
*           Sebastian.Koch@Infineon.com
* Support:  Support@Infineon.com
*           www.Infineon.com/support
* 
* ------------------------------------------------------------------------------
* 
* This library contains models of the following INFINEON transistors: 
* 
* Product          DeviceType  Level  VDSmax/V  RDSonmax/mOhm  IDmax/A  Package           L3-ModelName      L1-ModelName         L0-ModelName 
* -----------------------------------------------------------------------------------------------------------------------------------------------------
* IAUTN12S5N017      OptiMOS     NL      120         1.7         300    HSOF-8.(TOLL)     IAUTN12S5N017     IAUTN12S5N017_L1     IAUTN12S5N017_L0  
* IAUTN12S5N018G     OptiMOS     NL      120         1.8         300    HSOG-8.(TOLG)     IAUTN12S5N018G    IAUTN12S5N018G_L1    IAUTN12S5N018G_L0  
* IAUTN12S5N018T     OptiMOS     NL      120         1.8         300    HDSOP-16.(TOLT)   IAUTN12S5N018T    IAUTN12S5N018T_L1    IAUTN12S5N018T_L0  
* 
* ------------------------------------------------------------------------------
* 
* Thermal nodes of level 3 models: 
* 
*  Tj:    Potential (temperature in °C) at junction (typically not connected) 
*  Tcase: Node where boundary condition (external heat sinks) must be connected.
*         Ideal heat sink can be modeled by using a voltage source stating the 
*         ambient temperature in °C between Tcase and ground. 
* 
* ------------------------------------------------------------------------------
* 
* This file also contains simplified models that are compatible to standard 
* Spice (Level 0) 
* 
* ------------------------------------------------------------------------------
* 
* History: 
* DD/MM/YY 
* 22/08/08 initial version based on "SFET5_120V_NL_IPT017N12NM6_Spice.lib"(Koch)
* 22/09/13 ATV products and technology core (S5_120_fa_var) added:        (Koch)
*            IAUTN12S5N017      IAUTN12S5N018G     IAUTN12S5N018T
* 22/10/20 Level 0 added for all products                                 (Koch)
* 
* ------------------------------------------------------------------------------
* 
* S5_120_fa_var: SFET5_120 NL
* 
* ------------------------------------------------------------------------------

* turning off LTspice's default 1 mOhm series damping resistance (R=0)
.options Thev_Induc=1

********************************************************************************
* Level 3 Models
********************************************************************************


.SUBCKT IAUTN12S5N017 drain gate source Tj Tcase PARAMS: dVth=0 dRdson=0 dgfs=0 dC=0 dVbr=0 dZth=0 Ls=1.5n Ld=1n Lg=3n

.PARAM Rs=198u      Rg=1.1       Rd=20u       Rmet=67u
.PARAM Inn=300      Unn=10       Rmax=1.7m    gmin=234.36
.PARAM RRf=500m     Rrbond=2m    Rtb=1.6      g2=998m
.PARAM act=27.01    Rsp=0.9

.FUNC  Pb(I,dT,Rb)     {Rb/(2*Rtb)*(I-limit((dT/(max(I,1n)*Rb)+RRf*I)*g2,0,I))**2}

X_1  d1 g s sp Tj S5_120_fa_var PARAMS: a={act} dVth={dVth} dRdson={dRdson} dgfs={dgfs} dC={dC} dVbr={dVbr} 
+                              Inn={Inn} Unn={Unn} Rmax={Rmax} gmin={gmin} Rsp={Rsp} Rs={Rs} Rp={Rd} Rmet={Rmet}
R_g    g1      g       {Rg}   
L_g    gate    g1      {Lg*if(dgfs==99,0,1)}
G_s    s1      s       VALUE={V(s1,s)/(Rs*(1+(limit(V(Tj),-200,999)-25)*4m)-Rmet)}
R_sa   s1      s       1Meg
L_s    source  s1      {Ls*if(dgfs==99,0,1)}
R_da   d1      d2      {Rd}
L_d    drain   d2      {Ld*if(dgfs==99,0,1)}
R_daux drain   d2      10
R_gaux gate    g1      10
R_saux source  s1      10

G_th   0       Tb      VALUE={Pb(abs(I(L_s)),V(Tj,Tcase),Rrbond*(1+(limit((V(Tb)+V(Tj))/2,-200,999)-25)*4m))}
C_thb  Tb      0       21.95m
R_thb  Tb      Tj      {Rtb} 
R_th1  Tj      t1      {1.22m+limit(dZth,0,1)*444.77u}
R_th2  t1      t2      {13.35m+limit(dZth,0,1)*4.94m}
R_th3  t2      t3      {29.42m+limit(dZth,0,1)*6.83m}
R_th4  t3      t4      {52.92m+limit(dZth,0,1)*37.96m}
R_th5  t4      Tcase   {158.93m+limit(dZth,0,1)*113.99m}
C_th1  Tj      0       376.039u
C_th2  t1      0       853.711u
C_th3  t2      0       3.51m
C_th4  t3      0       4.76m
C_th5  t4      0       81.725m
C_th6  Tcase   0       30m

.ENDS

**********

.SUBCKT IAUTN12S5N018G drain gate source Tj Tcase PARAMS: dVth=0 dRdson=0 dgfs=0 dC=0 dVbr=0 dZth=0 Ls=1.5n Ld=1n Lg=3n

.PARAM Rs=218u      Rg=1.1       Rd=20u       Rmet=67u
.PARAM Inn=300      Unn=10       Rmax=1.8m    gmin=232.67
.PARAM RRf=500m     Rrbond=2m    Rtb=1.6      g2=998m
.PARAM act=27.01    Rsp=0.9

.FUNC  Pb(I,dT,Rb)     {Rb/(2*Rtb)*(I-limit((dT/(max(I,1n)*Rb)+RRf*I)*g2,0,I))**2}

X_1  d1 g s sp Tj S5_120_fa_var PARAMS: a={act} dVth={dVth} dRdson={dRdson} dgfs={dgfs} dC={dC} dVbr={dVbr} 
+                              Inn={Inn} Unn={Unn} Rmax={Rmax} gmin={gmin} Rsp={Rsp} Rs={Rs} Rp={Rd} Rmet={Rmet}
R_g    g1      g       {Rg}   
L_g    gate    g1      {Lg*if(dgfs==99,0,1)}
G_s    s1      s       VALUE={V(s1,s)/(Rs*(1+(limit(V(Tj),-200,999)-25)*4m)-Rmet)}
R_sa   s1      s       1Meg
L_s    source  s1      {Ls*if(dgfs==99,0,1)}
R_da   d1      d2      {Rd}
L_d    drain   d2      {Ld*if(dgfs==99,0,1)}
R_daux drain   d2      10
R_gaux gate    g1      10
R_saux source  s1      10

G_th   0       Tb      VALUE={Pb(abs(I(L_s)),V(Tj,Tcase),Rrbond*(1+(limit((V(Tb)+V(Tj))/2,-200,999)-25)*4m))}
C_thb  Tb      0       21.95m
R_thb  Tb      Tj      {Rtb} 
R_th1  Tj      t1      {1.22m+limit(dZth,0,1)*444.77u}
R_th2  t1      t2      {13.35m+limit(dZth,0,1)*4.94m}
R_th3  t2      t3      {29.42m+limit(dZth,0,1)*6.83m}
R_th4  t3      t4      {52.92m+limit(dZth,0,1)*37.96m}
R_th5  t4      Tcase   {158.93m+limit(dZth,0,1)*113.99m}
C_th1  Tj      0       376.039u
C_th2  t1      0       853.711u
C_th3  t2      0       3.51m
C_th4  t3      0       4.76m
C_th5  t4      0       81.725m
C_th6  Tcase   0       30m

.ENDS

**********

.SUBCKT IAUTN12S5N018T drain gate source Tj Tcase PARAMS: dVth=0 dRdson=0 dgfs=0 dC=0 dVbr=0 dZth=0 Ls=2n Ld=2n Lg=3n

.PARAM Rs=218u      Rg=1.1       Rd=35u       Rmet=67u
.PARAM Inn=300      Unn=10       Rmax=1.8m    gmin=231.06
.PARAM RRf=500m     Rrbond=2m    Rtb=1.6      g2=830m
.PARAM act=27.01    Rsp=0.9

.FUNC  Pb(I,dT,Rb)     {Rb/(2*Rtb)*(I-limit((dT/(max(I,1n)*Rb)+RRf*I)*g2,0,I))**2}

X_1  d1 g s sp Tj S5_120_fa_var PARAMS: a={act} dVth={dVth} dRdson={dRdson} dgfs={dgfs} dC={dC} dVbr={dVbr} 
+                              Inn={Inn} Unn={Unn} Rmax={Rmax} gmin={gmin} Rsp={Rsp} Rs={Rs} Rp={Rd} Rmet={Rmet}
R_g    g1      g       {Rg}   
L_g    gate    g1      {Lg*if(dgfs==99,0,1)}
G_s    s1      s       VALUE={V(s1,s)/(Rs*(1+(limit(V(Tj),-200,999)-25)*4m)-Rmet)}
R_sa   s1      s       1Meg
L_s    source  s1      {Ls*if(dgfs==99,0,1)}
R_da   d1      d2      {Rd}
L_d    drain   d2      {Ld*if(dgfs==99,0,1)}
R_daux drain   d2      10
R_gaux gate    g1      10
R_saux source  s1      10

G_th   0       Tb      VALUE={Pb(abs(I(L_s)),V(Tj,Tcase),Rrbond*(1+(limit((V(Tb)+V(Tj))/2,-200,999)-25)*4m))}
C_thb  Tb      0       21.95m
R_thb  Tb      Tj      {Rtb} 
R_th1  Tj      t1      {1.22m+limit(dZth,0,1)*444.77u}
R_th2  t1      t2      {13.35m+limit(dZth,0,1)*4.94m}
R_th3  t2      t3      {29.42m+limit(dZth,0,1)*6.83m}
R_th4  t3      t4      {52.92m+limit(dZth,0,1)*37.96m}
R_th5  t4      Tcase   {158.93m+limit(dZth,0,1)*113.99m}
C_th1  Tj      0       376.039u
C_th2  t1      0       853.711u
C_th3  t2      0       3.51m
C_th4  t3      0       4.76m
C_th5  t4      0       81.725m
C_th6  Tcase   0       30m

.ENDS



********************************************************************************
* Level 1 Models
********************************************************************************

.SUBCKT IAUTN12S5N017_L1 drain gate source PARAMS: dVth=0 dRdson=0 dgfs=0 dC=0 dVbr=0 Ls=1.5n Ld=1n Lg=3n

.PARAM Rs=198u      Rg=1.1       Rd=20u       Rmet=67u
.PARAM Inn=300      Unn=10       Rmax=1.7m    gmin=234.36
.PARAM act=27.01    Rsp=0.9

X_1  d1 g s sp Tj1 S5_120_fa_var PARAMS: a={act} dVth={dVth} dRdson={dRdson} dgfs={dgfs} dC={dC} dVbr={dVbr} 
+                               Inn={Inn} Unn={Unn} Rmax={Rmax} gmin={gmin} Rsp={Rsp} Rs={Rs} Rp={Rd} Rmet={Rmet}
R_g    g1     g    {Rg}   
L_g    gate   g1   {Lg*if(dgfs==99,0,1)}
G_s    s1     s    VALUE={V(s1,s)/(Rs*(1+(limit(V(Tj),-200,999)-25)*4m)-Rmet)}
R_sa   s1     s    1Meg
L_s    source s1   {Ls*if(dgfs==99,0,1)}
R_da   d1     d2   {Rd}
L_d    drain  d2   {Ld*if(dgfs==99,0,1)}
R_daux drain  d2   10
R_gaux gate   g1   10
R_saux source s1   10

E_2    Tj     w    VALUE={TEMP}
V_p    Tj1    Tj   0
R_1    Tj     Tj1  1u
G_power  0    Tj   VALUE={V(s1,s)*V(s1,s)/(Rs*(1+(limit(V(Tj),-200,999)-25)*4m)-Rmet)+V(g,g1)*V(g,g1)/Rg+V(d1,d2)*V(d1,d2)/Rd+I(V_p)}
R_2      w    0    1u

.ENDS

**********

.SUBCKT IAUTN12S5N018G_L1 drain gate source PARAMS: dVth=0 dRdson=0 dgfs=0 dC=0 dVbr=0 Ls=1.5n Ld=1n Lg=3n

.PARAM Rs=218u      Rg=1.1       Rd=20u       Rmet=67u
.PARAM Inn=300      Unn=10       Rmax=1.8m    gmin=232.67
.PARAM act=27.01    Rsp=0.9

X_1  d1 g s sp Tj1 S5_120_fa_var PARAMS: a={act} dVth={dVth} dRdson={dRdson} dgfs={dgfs} dC={dC} dVbr={dVbr} 
+                               Inn={Inn} Unn={Unn} Rmax={Rmax} gmin={gmin} Rsp={Rsp} Rs={Rs} Rp={Rd} Rmet={Rmet}
R_g    g1     g    {Rg}   
L_g    gate   g1   {Lg*if(dgfs==99,0,1)}
G_s    s1     s    VALUE={V(s1,s)/(Rs*(1+(limit(V(Tj),-200,999)-25)*4m)-Rmet)}
R_sa   s1     s    1Meg
L_s    source s1   {Ls*if(dgfs==99,0,1)}
R_da   d1     d2   {Rd}
L_d    drain  d2   {Ld*if(dgfs==99,0,1)}
R_daux drain  d2   10
R_gaux gate   g1   10
R_saux source s1   10

E_2    Tj     w    VALUE={TEMP}
V_p    Tj1    Tj   0
R_1    Tj     Tj1  1u
G_power  0    Tj   VALUE={V(s1,s)*V(s1,s)/(Rs*(1+(limit(V(Tj),-200,999)-25)*4m)-Rmet)+V(g,g1)*V(g,g1)/Rg+V(d1,d2)*V(d1,d2)/Rd+I(V_p)}
R_2      w    0    1u

.ENDS

**********

.SUBCKT IAUTN12S5N018T_L1 drain gate source PARAMS: dVth=0 dRdson=0 dgfs=0 dC=0 dVbr=0 Ls=2n Ld=2n Lg=3n

.PARAM Rs=218u      Rg=1.1       Rd=35u       Rmet=67u
.PARAM Inn=300      Unn=10       Rmax=1.8m    gmin=231.06
.PARAM act=27.01    Rsp=0.9

X_1  d1 g s sp Tj1 S5_120_fa_var PARAMS: a={act} dVth={dVth} dRdson={dRdson} dgfs={dgfs} dC={dC} dVbr={dVbr} 
+                               Inn={Inn} Unn={Unn} Rmax={Rmax} gmin={gmin} Rsp={Rsp} Rs={Rs} Rp={Rd} Rmet={Rmet}
R_g    g1     g    {Rg}   
L_g    gate   g1   {Lg*if(dgfs==99,0,1)}
G_s    s1     s    VALUE={V(s1,s)/(Rs*(1+(limit(V(Tj),-200,999)-25)*4m)-Rmet)}
R_sa   s1     s    1Meg
L_s    source s1   {Ls*if(dgfs==99,0,1)}
R_da   d1     d2   {Rd}
L_d    drain  d2   {Ld*if(dgfs==99,0,1)}
R_daux drain  d2   10
R_gaux gate   g1   10
R_saux source s1   10

E_2    Tj     w    VALUE={TEMP}
V_p    Tj1    Tj   0
R_1    Tj     Tj1  1u
G_power  0    Tj   VALUE={V(s1,s)*V(s1,s)/(Rs*(1+(limit(V(Tj),-200,999)-25)*4m)-Rmet)+V(g,g1)*V(g,g1)/Rg+V(d1,d2)*V(d1,d2)/Rd+I(V_p)}
R_2      w    0    1u

.ENDS



********************************************************************************
* Level 0 Models
********************************************************************************

.SUBCKT IAUTN12S5N017_L0  drain  gate  source

L_g     gate   g1   3n
L_d     drain  d1   1n
L_s     source s1   1.5n
R_daux  drain  d1   10
R_gaux  gate   g1   10
R_saux  source s1   10
R_s     s1     s2   198u TC=3m

R_g     g1    g2    1.1
M_1     d2    g2    s2    s2    DMOS   L=1u   W=1u
.MODEL  DMOS  NMOS ( KP=480.8  VTO=4.38  THETA=0  VMAX=1.5e5  ETA=0.003  CGDO=1f  CGSO=1f  CGBO=1f  IS=0  LEVEL=3 )
R_d     d1    d2    0.91m TC=6m

D_bd    s2    d2    Dbt
.MODEL  Dbt   D ( BV=125   M=0.5  CJO=4.86n  VJ=2 )
R_sp    s2    s3    0.9
D_bd1   s3    d2    Dbt1
.MODEL  Dbt1  D ( BV=1000   M=0.5  CJO=6.65n  VJ=2 )
D_body  s2    21    DBODY
.MODEL  DBODY D ( IS=115.9p  N=1.1  RS=0.02u  EG=1.12  TT=20n )
R_diode d1    21    0.26m TC=1m

.MODEL  sw   NMOS ( VTO=0  KP=10  LAMBDA=1m  CGDO=1f  CGSO=1f  CGBO=1f  IS=0  LEVEL=1 )
M_aux   g2   c    a    a    sw   L=10u   W=10u
M_aux2  b    d    g2   g2   sw   L=10u   W=10u
E_aux   c    a    d2   g2   1
E_aux2  d    g2   d2   g2   -1
C_ox    b    d2   0.75n
.MODEL  DGD  D ( M=0.5  CJO=0.75n  VJ=0.5 )
* R_par   b    d2   1Meg
D_gd    a    d2   DGD
* R_par2  d2   a    10Meg
C_gs    g2   s2   8.2n

.ENDS  IAUTN12S5N017_L0

******

.SUBCKT IAUTN12S5N018G_L0  drain  gate  source

L_g     gate   g1   3n
L_d     drain  d1   1n
L_s     source s1   1.5n
R_daux  drain  d1   10
R_gaux  gate   g1   10
R_saux  source s1   10
R_s     s1     s2   218u TC=3m

R_g     g1    g2    1.1
M_1     d2    g2    s2    s2    DMOS   L=1u   W=1u
.MODEL  DMOS  NMOS ( KP=480.8  VTO=4.38  THETA=0  VMAX=1.5e5  ETA=0.003  CGDO=1f  CGSO=1f  CGBO=1f  IS=0  LEVEL=3 )
R_d     d1    d2    0.91m TC=6m

D_bd    s2    d2    Dbt
.MODEL  Dbt   D ( BV=125   M=0.5  CJO=4.86n  VJ=2 )
R_sp    s2    s3    0.9
D_bd1   s3    d2    Dbt1
.MODEL  Dbt1  D ( BV=1000   M=0.5  CJO=6.65n  VJ=2 )
D_body  s2    21    DBODY
.MODEL  DBODY D ( IS=115.9p  N=1.1  RS=0.02u  EG=1.12  TT=20n )
R_diode d1    21    0.26m TC=1m

.MODEL  sw   NMOS ( VTO=0  KP=10  LAMBDA=1m  CGDO=1f  CGSO=1f  CGBO=1f  IS=0  LEVEL=1 )
M_aux   g2   c    a    a    sw   L=10u   W=10u
M_aux2  b    d    g2   g2   sw   L=10u   W=10u
E_aux   c    a    d2   g2   1
E_aux2  d    g2   d2   g2   -1
C_ox    b    d2   0.75n
.MODEL  DGD  D ( M=0.5  CJO=0.75n  VJ=0.5 )
* R_par   b    d2   1Meg
D_gd    a    d2   DGD
* R_par2  d2   a    10Meg
C_gs    g2   s2   8.2n

.ENDS  IAUTN12S5N018G_L0

******

.SUBCKT IAUTN12S5N018T_L0  drain  gate  source

L_g     gate   g1   3n
L_d     drain  d1   2n
L_s     source s1   2n
R_daux  drain  d1   10
R_gaux  gate   g1   10
R_saux  source s1   10
R_s     s1     s2   218u TC=3m

R_g     g1    g2    1.1
M_1     d2    g2    s2    s2    DMOS   L=1u   W=1u
.MODEL  DMOS  NMOS ( KP=480.8  VTO=4.38  THETA=0  VMAX=1.5e5  ETA=0.003  CGDO=1f  CGSO=1f  CGBO=1f  IS=0  LEVEL=3 )
R_d     d1    d2    0.92m TC=6m

D_bd    s2    d2    Dbt
.MODEL  Dbt   D ( BV=125   M=0.5  CJO=4.86n  VJ=2 )
R_sp    s2    s3    0.9
D_bd1   s3    d2    Dbt1
.MODEL  Dbt1  D ( BV=1000   M=0.5  CJO=6.65n  VJ=2 )
D_body  s2    21    DBODY
.MODEL  DBODY D ( IS=115.9p  N=1.1  RS=0.02u  EG=1.12  TT=20n )
R_diode d1    21    0.26m TC=1m

.MODEL  sw   NMOS ( VTO=0  KP=10  LAMBDA=1m  CGDO=1f  CGSO=1f  CGBO=1f  IS=0  LEVEL=1 )
M_aux   g2   c    a    a    sw   L=10u   W=10u
M_aux2  b    d    g2   g2   sw   L=10u   W=10u
E_aux   c    a    d2   g2   1
E_aux2  d    g2   d2   g2   -1
C_ox    b    d2   0.75n
.MODEL  DGD  D ( M=0.5  CJO=0.75n  VJ=0.5 )
* R_par   b    d2   1Meg
D_gd    a    d2   DGD
* R_par2  d2   a    10Meg
C_gs    g2   s2   8.2n

.ENDS  IAUTN12S5N018T_L0

******


********************************************************************************
* Technology Models
********************************************************************************

.SUBCKT S5_120_fa_var dd g s0 sp Tj PARAMS: a=1 dVth=0 dRdson=0 dgfs=0 dC=0 dVbr=0 
+ Inn=1 Unn=1 Rmax=0 gmin=1 Rsp=1 Rs=1 Rp=1 Rmet=1u

* corner parameters
.PARAM  dVthmax=0.5   dCmax=0.3   dVbrmax=5

* technology parameters
.PARAM  Fm=0.2     Fn=0.5      al=0.5
.PARAM  c=1.12     Vth0=4.56   auth=3.5m
.PARAM  dvx=550m   dvgs=200m   auth_sub=3.5m
.PARAM  UT=100m    ab=60m      lB=-23       UB=124

.PARAM  b0=20      p0=9.73     p1=-31.4m    p2=50u

.PARAM  Rd=23.1m   nmu=3.08    Tref=298     T0=273      lnIsj=-26.5
.PARAM  ndi=1.1    nisj=2.24   Rdi=5.3m     nmu2=0
.PARAM  td=25n     ta=25n
.PARAM  Rf=0.35    nmu3=1.0    rpara=300u

.PARAM  kbq=86.2u

* Cgs
.PARAM  f3=253p    f3b=0

* Cgfp
.PARAM  f3a=50p

* Cds
.PARAM qs1=35.5p   qs2=126.0p  qs3=-27.0m
.PARAM qs4=44.3p   qs5=-0.690
.PARAM q81=44.7p   f2r=1.31
.PARAM x0=36.8     x1=79.4     dx={x1-x0}

* Cgd
.PARAM  ps0=15p    ps1=6.82p   ps2=-0.430
.PARAM  ps3=34.2p  ps4=-65.1m  ps5=0.535p
.PARAM  ps6=6p     f5=1.4p
.PARAM  x2=28.4    x3=71.4     dx2={x3-x2}

.PARAM  Vth={Vth0+dVthmax*dVth}
.PARAM  q0={b0*((T0/Tref)**nmu3)*a}
.PARAM  q1={(Unn-Inn*Rs-Vth0)*q0}
.PARAM  q2={(Fm*sqrt(0.4)-c)*Inn*q0}
.PARAM  Rlim={(q1+2*q2*Rmax-sqrt(max(q1**2+4*q2,0)))/(2*q2)}
.PARAM  dRd={Rd/a+if(dVth==0,limit(dRdson,0,1)*max(Rlim-Rd/a-Rs-Rp,0),0)}
.PARAM  bm={c/((1/gmin-Rs)**2*Inn*a*(T0/Tref)**nmu3)}
.PARAM  bet={b0+(b0-bm)*if(dRdson==0,if(dVth==0,limit(dgfs,-1,0),0),0)}
.PARAM  dC1={1+dCmax*limit(dC,0,1)}
* .PARAM  dC2={1+1.5*dCmax*limit(dC,0,1)}

.PARAM  Cgs0={(f3*a+sqrt(a)*f3b)*dC1}
.PARAM  Cgs1={f3a*a*dC1}

.PARAM  dRdi={Rdi/a}

.PARAM  Cox1={(ps1*a+ps0*sqrt(a))*dC1}
.PARAM  Cox2={ps3*a*dC1}
.PARAM  Cox3={(ps5*a+ps6)*dC1}
.PARAM  Cox4={(f5*a+(ps5*a+ps6))*dC1}

.PARAM  Cds0={qs1*a*dC1}
.PARAM  Cds1={qs2*(1+f2r/sqrt(a))*a*dC1}
.PARAM  Cds2={qs4*a*dC1}
.PARAM  Cds3={(q81+qs1)*a*dC1}

* .FUNC  VBR(Usps)    {max(UB+min(Usps,dUmax)*s1+max(Usps-dUmax,0)*s2,Umin)}
.FUNC  VBR(Usps)    {UB+dVbrmax*dVbr}

.FUNC Ue(g,y,w)  {(g-Vth+auth*(w-Tref)+Fm*y**Fn)}
.FUNC Ue1(g,y,w) {Ue(g,y,w)+(1+limit(Ue(g,y,w)+dvx,0,1)**2*(2*limit(Ue(g,y,w)+dvx,0,1)-3))*(dvgs+(auth_sub-auth)*(w-Tref))}

.FUNC Ia(Uee,p,pp,z1) {if(Uee>pp,(Uee-c*z1)*z1,p*(pp-p)/c*exp((Uee-pp)/p))}
.FUNC Ih(Uds,T,p,Uee) {bet*(T0/T)**nmu3*Ia(Uee,p,min(2*p,p+c*Uds),min(Uds,Uee/(2*c)))}
.FUNC Jh(d,g,w,y,s,x) {a*((Ih(s*y+min(d,0),w,(p0+(p1+p2*w)*w)*kbq*w,Ue1(g,y,w))+exp(min(lB+(d-UB-ab*(w-Tref))/UT,24))))}

.FUNC  Idiode(Usd,Tj,Iss) {exp(min(log(Iss)+Usd/(ndi*kbq*Tj),7))-Iss}
.FUNC  Idiod(Usd,Tj)      {a*Idiode(Usd,Tj,exp(min(lnIsj+(Tj/Tref-1)*1.12/(ndi*kbq*Tj),7))*(Tj/Tref)**nisj)}

.FUNC  Pr(Vss0,Vssp)  {Vss0*Vss0/max(Rmet,1u)+Vssp*Vssp/Rsp}

.FUNC QCds(x) {Cds3*min(x,x1)+Cds0*max(x-x1,0)+(Cds3-Cds0)*((limit(x,x0,x1)-x0)**3/(dx*dx)*((limit(x,x0,x1)-x0)/(2*dx)-1))}
.FUNC QCdg(x) {Cox4*min(x,x3)+Cox3*max(x-x3,0)+(Cox4-Cox3)*((limit(x,x2,x3)-x2)**3/(dx2*dx2)*((limit(x,x2,x3)-x2)/(2*dx2)-1))}


E_Edg1     d   ox    VALUE {if(V(d,g)>0,V(d,g)-(exp(ps2*max(V(d,g),0))-1)/ps2,0)}
C_Cdg1    ox   g     {Cox1}
E_Edg2     d   ox1   VALUE {if(V(d,g)>0,V(d,g)-(exp(ps4*max(V(d,g),0))-1)/ps4,0)}
C_Cdg2   ox1   g     {Cox2}
E_Edg3     d   ox2   VALUE {V(d,g)-QCdg(V(d,g))/Cox4}
C_Cdg3   ox2   g     {Cox4} 

E_Eds      d   edep  VALUE {V(d,s)-QCds(V(d,s))/Cds3}
C_Cds  edep    s    {Cds3/2} 

E_Eds1     d   edep1 VALUE {V(d,sp)-QCds(V(d,sp))/Cds3}
C_Cds1 edep1   sp    {Cds3/2} 
E_Eds2     d   edep2 VALUE {if(V(d,sp)>0,V(d,sp)-(exp(qs5*max(V(d,sp),0))-1)/qs5,0)}
C_Cds2 edep2   sp    {Cds2}
E_Eds3     d   edep3 VALUE {if(V(d,sp)>0,V(d,sp)-(exp(qs3*max(V(d,sp),0))-1)/qs3,0)}
C_Cds3 edep3   sp    {Cds1}

C_Cgs     g    s      {Cgs0}
C_Cgs1    g    sp     {Cgs1}

R_fp      s    sp     {Rsp}

G_chan   d5a   s  VALUE={Jh(V(d5a,s),V(g,s),T0+limit(V(Tj),-200,300),(sqrt(1+4*al*abs(V(d5a,s)))-1)/2/al,sgn(V(d5a,s)),V(sp,s))}
R_d06    d5a  d5  1u
V_sm     d    d5  0
G_RMos   d1    d  VALUE={V(d1,d)/(Rf*dRd+(1-Rf)*dRd*((limit(V(Tj),-200,999)+T0)/Tref)**nmu)/(1+rpara*(I(V_sense)/a)**2)}
V_sense  dd   d1  0
G_diode   s   d3  VALUE={Idiod(V(s,d3),T0+limit(V(Tj),-200,499))}
G_Rdio   d2   d1  VALUE={V(d2,d1)/(dRdi*((limit(V(Tj),-200,999)+T0)/Tref)**nmu2)}
V_sense2 d2   d3  0

* includes RevRec, but has no Tj dependence...
* D_body s d3 dbody
* .model dbody D ( BV={UB*10} CJO={Cds0/100} TT={ta} IS={a*exp(lnIsj)} m=0.3 RS={dRdi*1m} n={ndi} XTI={nisj} )

R_1        g    s  1G
R_d01      d    s  500Meg
R_d02     d2    s  500Meg
R_d03     d1    d  1k
R_ssp     g    sp  100Meg

R_met      s    s0 {Rmet}

G_th      0   Tj  VALUE={(I(V_sense)-I(V_sense2))*V(d1,d)+I(V_sm)*V(d,s)+I(V_sense2)*V(d1,s)+Pr(V(s,s0),V(s,sp))}

.ENDS