*************************************************************************
* ver 1.1, Jan 29, 2024, By Geetak Gupta, Nihal Singh @ Transphorm
*************************************************************************
* Level 1 model (L1T1)
*************************************************************************
* The model is an approximation of the device.
* The model may not show the true device performance under all conditions.
* The model only guarantees the accuracy of the key parameters (Ron, Ciss, 
* Coss, Crss, Eoss, Qoss, and Qrr) in the current data sheet.
* Please refer to the current datasheet for the most up to date specifications
* of the device.
* Transphorm Inc. does not assume any liability arising from this use.
* Transphorm Inc. reserves the right to change models without prior notice.
*************************************************************************
 
.subckt TP65H070G4PS_TO220 drain gate source
 
.param fsat1={144} fsat2={8.5} fsat3={4.9}
.param frp1={0.55} frp2={1.33} frp3={6.35} frp4={0.25}
.param frev1={142} frev2={0.264} frev3={0.83}
.param fgd1={2.1} fgd2={1.05} fgd3={0.177}
.param fsd1={73} fsd2={45} fsd3={0.057}
.param fgs1={646}

Ls source 101 1n
Rls 101 S 0.01m
Lg gate 201 3n
Rlg 201 G 0.01m
Ld drain 301 1n
Rld 301 D 0.01m

Rgs G S 1e8
Rgd G D 1e8
Rds D S 1e8

Cgs G S {fgs1*1e-12}

Csd1 S 105 {fsd1*1e-12}
Csd2 S 105 Q = 1e-9*2*fsd2*((1/(1+exp(-fsd3*(x))))-0.5)
Rdss 105 D 4

Cgd1 G D {fgd1*1e-12}
Cgd2 G D Q = 1e-9*2*fgd2*((1/(1+exp(-fgd3*(x))))-0.5)

Rs S S1 0.1m
Rd D D1 0.1m
Rg G G1 0.1m
 
.func Idsat(t) if(V(G1,S1) < fsat3, 0, if ( V(G1,S1) < fsat2, fsat1*(V(G1,S1)-fsat3)/(fsat2-fsat3), fsat1))
.func Rp(t) (frp1*((1/(1+exp(frp2*(V(G1,S1)-frp3))))) + frp4)
 
bchnl D1 S1 I = {if ( V(G1,S1) > fsat3, 2*Idsat(time)*((1/(1+exp(-Rp(time)*V(D1,S1)))) - (0.5)), 0)}
 
bdiode D1 S1 I = {if ( V(D1,S1) < -frev3, -2*frev1*((1/(1+exp(-frev2*(abs(V(D1,S1))-frev3))))-0.5), 0)}
 
.ends TP65H070G4PS_TO220