Lossy transmission line with frequency dependent primary parameters

Is there a way to model a lossy transmission line with frequency dependent primary parameters, e.g., higher R’ for higher frequency due to skin effect, in QSpice?
I tried to use the method described in the article “SPICE Simulation of Transmission Lines by the Telegrapher’s Method” by Roy McCammon.
It uses Laplace expressions to model this kind of transmission line based on the telegrapher’s equations. (The model I tried to use attached below).
However, it uses the exp() function in the Laplace expressions and therefore won’t run in time-domain (.tran) simulations.
Is there a way to model this, that is usable in time-domain (.tran) simulations?

.param len=50 ; lenght in [m]
.param Lcon=20n ; convergence inductance
+ C=82p ; the value of capacitance at dc [F/m]
+ Gdc=0.2p ; the value of conductance at dc [S/m] (value>0 for numerical reasons)
+ Rdc=4.9m ; the value of resistance at dc  [O/m]
+ Ldc=262n ; the value of inductance at dc [H/m]
+ Linf=201n ; inductance at infinite frequency [H/m]
+ Ldel=(Ldc-Linf) ; inductance parameter
+ Zinf=(Linf/C)**0.5 ; characteristic impedance at infinite frequency
+ Yinf=1/Zinf ; characteristic conductance at infinite frequency
+ F2=1e9 ; the highest frequency in [Hz]
+ W2=6.28318*F2 ; the highest frequency in [rad/sec]
+ G1=11.1u ; the value of conductance at F1  [S/m]
+ G2=114.93u ; the value of conductance at F2  [S/m]
+ Rac=1.1 ; the value of resistance at F2  [O/m]
+ F1=1e8 ; the second highest frequency in [Hz]
+ A=2.4 ; inductance parameter
+ cp=Log(G2/G1)/Log(F2/F1)/2 ; conductance parameter
+ WL=6.28318*13e3 ; inductance parameter frequency dependent inductance transition frequency [rad/sec]
+ WR=W2*(Rdc**2)/(((Rac**4)-(Rdc**4))**0.5) ; resistance parameter
.subckt single_mode_xline_1 L1 R1
G1 N1 0 N1 0 Laplace=(((((Gdc+G2*(-(s/w2)^2)^cp)+s*C)/((Rdc*(1-(s/wR)^2)^0.25)+s*(Linf+Ldel/(1+A*((-(s/wL)^2)^0.5)-(s/wL)^2)^0.25)))^0.5))-Yinf
G2 0 N1 N2 0 1
G3 0 L1 N2 0 1
V1 L1 N1 0 Rser=0
H1 N4 0 V1 1
G4 N6 0 N6 0 Laplace=(((((Gdc+G2*(-(s/w2)^2)^cp)+s*C)/((Rdc*(1-(s/wR)^2)^0.25)+s*(Linf+Ldel/(1+A*((-(s/wL)^2)^0.5)-(s/wL)^2)^0.25)))^0.5))-Yinf
G5 0 N6 N5 0 1
G6 0 R1 N5 0 1
V2 R1 N6 0 Rser=0
H2 N3 0 V2 1
R1 N6 0 {Zinf}
R2 N1 0 {Zinf}
G7 0 N2 N3 0 Laplace=exp(-len*((((Rdc*(1-(s/wR)^2)^.25)+s*(Linf+Ldel/(1+A*((-(s/wL)^2)^.5)-(s/wL)^2)^.25))*(Gdc+G2*(-(s/w2)^2)^cp+s*C))^.5))/(s*Lcon+1)
L1 N5 0 {Lcon} Rser=1
G8 0 N5 N4 0 Laplace=exp(-len*((((Rdc*(1-(s/wR)^2)^.25)+s*(Linf+Ldel/(1+A*((-(s/wL)^2)^.5)-(s/wL)^2)^.25))*(Gdc+G2*(-(s/w2)^2)^cp+s*C))^.5))/(s*Lcon+1)
L2 N2 0 {Lcon} Rser=1
.ends single_mode_xline_1

I am also interested in a solution for this problem. In the paper mentioned above Roy points out the measured attenuation characteristic of a transmission line and how to derive the parameters for this model.
I think, his approach makes a lot of sense for a transmission line simulation.